Amiga Repair Kit/Amiga Repair Kit.iso/Freely_Distributable/DisKey_3.0_Preview_3/Install.DisKey

Text File | 1994-11-16 | 11.2 KB | 457 lines

;$VER: DisKey.Install 1.4 (16-11-94)
;
; $Id: Install.DisKey,v 21.1 1994/11/16 13:01:07 Angela Schmidt Exp $
;
;Dies ist das Installscript für DisKey!


(set langnum
    (askchoice
        (prompt "")
        (help @askchoice-help)
        (choices
            "Deutsch"
            "English"
            "Français"
        )
        (default
            (if (patmatch @language "Deutsch")
                0
                (if (patmatch @language "English")
                    1
                    (if (patmatch @language "Français")
                        2
                        0
                    )
                    0
                )
            )
        )
    )
)

(if (= langnum 0) (set langstring "Deutsch"))
(if (= langnum 1) (set langstring "English"))
(if (= langnum 2) (set langstring "Français"))

; Hier folgen die Strings, die für die deutsche Übersetzung benötigt
; werden. Bei Übersetzungen in andere Sprachen einfach den folgenden
; Block komplett kopieren und die Texte ändern. Die Steuerzeichen
; sollten unverändert bleiben! Wer irgendwo eine Zeile hinzufügen oder
; löschen möchte, muß dir Anzahl der "%s" entsprechend anpassen - für
; jede Zeile steht ein "%s".

(if (patmatch langstring "Deutsch")
    (
        (set answer_yes "Ja")
        (set answer_no "Nein")
        (set choose_diskey_directory
            (
                "%s%s"
                "Bitte wählen Sie das Verzeichnis, in dem Sie DisKey installieren wollen! "
                "In diesem Verzeichnis wird automatisch ein Verzeichnis mit dem Namen \"DisKey_3.0\" angelegt!"
            )
        )
        (set copy_nonlocale_strings
            "Sollen auch die Übersetzungstabellen für Benutzer ohne locale.library kopiert werden?"
        )
        (set help_copy_nonlocale_strings
            (
                "%s%s%s"
                "Diese Option ist sinnvoll, wenn Sie zwischendurch ohne locale.library - zum Beispiel mit OS 2.04 oder gar Kickstart 1.3 - arbeiten. "
                "Wenn Sie \"Nein\" wählen, wird sich DisKey dann nur noch Englisch mit Ihnen "
                "unterhalten. Falls Sie jedoch \"Ja\" anklicken, werden Sie auch bei fehlender locale.library mit Ihrer Lieblingssprache verwöhnt werden!"
            )
        )
        (set select_languages
            "Bitte wählen Sie die Sprachen, die Sie installieren möchten!"
        )
        (set select_fs_modules
            "Bitte wählen Sie die externen Dateisystem-Module, die Sie installieren möchten!"
        )
        (set help_select_fs_modules
            (
                "%s%s%s"
                "Bisher sind folgende Module verfügbar:\n\n"
                "rdskfs - Modul zum Bearbeiten der Rigid-Disk-Blöcke einer Festplatte\n"
                "cosyfs - Modul zum Bearbeiten einer mit CosyFS formatierten Festplatte\n"
            )
        )
        (set ready_to_install_1
            "Sind Sie bereit, DisKey V3.0 im Verzeichnis "
        )
        (set ready_to_install_2
            " zu installieren?"
        )
        (set install_fsmodules
            "Installiere Dateisystem-Module..."
        )
        (set install_languages
            "Installiere Sprachen..."
        )
        (set copylib_patternlibrary
            (
                "%s%s"
                "Die pattern.library wird u. a. zum Patternmatching benötigt - sie muß also nicht "
                "zwingend installiert werden!"
            )
        )
        (set copylib_dislibrary
            (
                "%s%s"
                "Die dis.library wird nur benötigt, falls Sie die Disassembler-Funktion von "
                "DisKey 3.0 benutzen möchten. Sie muß also nicht zwingend installiert werden!"
            )
        )
        (set copylib_reqlibrary
            (
                "%s%s"
                "Die req.library wird nur für den Color-Requester benötigt - sie muß also nicht "
                "zwingend installiert werden!"
            )
        )
    )
)
(if (patmatch langstring "English")
    (abort "English texts are not yet translated, sorry!")
)
(if (patmatch langstring "Français")
    (abort "Français n'est pas encore traduiré, je regrette!")
)

(set todir @default-dest)
(set todir
    (askdir
        (prompt choose_diskey_directory)
        (help @askdir-help)
        (default todir)
    )
)
(set @default-dest todir)
(set newdir (tackon todir "DisKey_3.0"))
(makedir newdir)
(if (exists (cat "DisKey_3.0.info"))
    (
        (run ("copy \"DisKey_3.0.info\" TO \"" (tackon todir "DisKey_3.0.info") "\""))
        (tooltype
            (dest newdir)
            (noposition)
        )
    )
    (
        (run ("copy SYS:System.info TO \"" (tackon todir "DisKey_3.0.info") "\""))
        (tooltype
            (dest newdir)
            (noposition)
        )
    )
)

(if (exists ("LOCALE:" (noreq)))
    (
        (set copynonlocale
            (askbool
                (prompt copy_nonlocale_strings)
                (help help_copy_nonlocale_strings)
                (default 1)
                (choices answer_yes answer_no)
            )
        )
    )
    (set copynonlocale 1)
)

(set numlangs 1)
(set lang_1 "English")
(foreach
    "DisKey_3.0/Catalogs"
    "#?"
    (
        (set numlangs (+ numlangs 1))
        (if (= numlangs 2)
            (set lang_2 @each-name)
        )
        (if (= numlangs 3)
            (set lang_3 @each-name)
        )
        (if (= numlangs 4)
            (set lang_4 @each-name)
        )
        (if (= numlangs 5)
            (set lang_5 @each-name)
        )
        (if (= numlangs 6)
            (set lang_6 @each-name)
        )
        (if (= numlangs 7)
            (set lang_7 @each-name)
        )
        (if (= numlangs 8)
            (set lang_8 @each-name)
        )
        (if (= numlangs 9)
            (set lang_9 @each-name)
        )
        (if (= numlangs 10)
            (set lang_10 @each-name)
        )
    )
)

(set language_bits
    (askoptions
        (prompt select_languages)
        (help @askoptions-help)
        (if (= numlangs 1)
            (choices lang_1)
        )
        (if (= numlangs 2)
            (choices lang_1 lang_2)
        )
        (if (= numlangs 3)
            (choices lang_1 lang_2 lang_3)
        )
        (if (= numlangs 4)
            (choices lang_1 lang_2 lang_3 lang_4)
        )
        (if (= numlangs 5)
            (choices lang_1 lang_2 lang_3 lang_4 lang_5)
        )
        (if (= numlangs 6)
            (choices lang_1 lang_2 lang_3 lang_4 lang_5 lang_6)
        )
        (if (= numlangs 7)
            (choices lang_1 lang_2 lang_3 lang_4 lang_5 lang_6 lang_7)
        )
        (if (= numlangs 8)
            (choices lang_1 lang_2 lang_3 lang_4 lang_5 lang_6 lang_7 lang_8)
        )
        (if (= numlangs 9)
            (choices lang_1 lang_2 lang_3 lang_4 lang_5 lang_6 lang_7 lang_8 lang_9)
        )
        (if (= numlangs 10)
            (choices lang_1 lang_2 lang_3 lang_4 lang_5 lang_6 lang_7 lang_8 lang_9 lang_10)
        )
        (default -1)
    )
)

(set numfs 0)
(foreach
    "DisKey_3.0/FileSystem"
    "#?.dkfs"
    (
        (set numfs (+ numfs 1))
        (if (= numfs 1)
            (set fs_1 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
        (if (= numfs 2)
            (set fs_2 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
        (if (= numfs 3)
            (set fs_3 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
        (if (= numfs 4)
            (set fs_4 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
        (if (= numfs 5)
            (set fs_5 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
        (if (= numfs 6)
            (set fs_6 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
        (if (= numfs 7)
            (set fs_7 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
        (if (= numfs 8)
            (set fs_8 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
        (if (= numfs 9)
            (set fs_9 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
        (if (= numfs 10)
            (set fs_10 (substr @each-name 0 (- (strlen @each-name) 5)))
        )
    )
)

(set fsmodule_bits
    (askoptions
        (prompt select_fs_modules)
        (help help_select_fs_modules "\n\n" @askoptions-help)
        (if (= numfs 1)
            (choices fs_1)
        )
        (if (= numfs 2)
            (choices fs_1 fs_2)
        )
        (if (= numfs 3)
            (choices fs_1 fs_2 fs_3)
        )
        (if (= numfs 4)
            (choices fs_1 fs_2 fs_3 fs_4)
        )
        (if (= numfs 5)
            (choices fs_1 fs_2 fs_3 fs_4 fs_5)
        )
        (if (= numfs 6)
            (choices fs_1 fs_2 fs_3 fs_4 fs_5 fs_6)
        )
        (if (= numfs 7)
            (choices fs_1 fs_2 fs_3 fs_4 fs_5 fs_6 fs_7)
        )
        (if (= numfs 8)
            (choices fs_1 fs_2 fs_3 fs_4 fs_5 fs_6 fs_7 fs_8)
        )
        (if (= numfs 9)
            (choices fs_1 fs_2 fs_3 fs_4 fs_5 fs_6 fs_7 fs_8 fs_9)
        )
        (if (= numfs 10)
            (choices fs_1 fs_2 fs_3 fs_4 fs_5 fs_6 fs_7 fs_8 fs_9 fs_10)
        )
        (default -1)
    )
)

(run ("protect %s rwed" (tackon newdir "DisKey")))
(run ("protect %s rwed" (tackon newdir "DisKey.info")))
(run ("protect %s rwed" (tackon newdir "DisKey.key")))
(run ("protect %s rwed" (tackon newdir "DisKeyStartupMacro.dkm")))
(run ("protect %s rwed" (tackon newdir "cmdshell.dk")))
(run ("protect %s rwed" (tackon newdir "DK")))
(run ("protect %s rwed" (tackon newdir "DK.info")))
(run ("protect %s rwed" (tackon newdir "DisKeyDebug")))
(run ("protect %s rwed" (tackon newdir "Inhibit")))
(copyfiles
    (prompt ready_to_install_1 todir ready_to_install_2)
    (source "DisKey_3.0")
    (pattern "(DisKey|DisKey.info|DisKey.key|DisKeyStartupMacro.dkm|cmdshell.dk|DK|DK.info|DisKeyDebug|Inhibit)")
    (dest newdir)
    (infos)
    (optional nofail force)
)

(if (NOT (= fsmodule_bits 0))
    (
        (working
            install_fsmodules
        )
        (set fstmpbit 0)
        (foreach
            "DisKey_3.0/FileSystem"
            "#?.dkfs"
            (
                (if (IN fsmodule_bits fstmpbit)
                    (
                        (run ("protect %s rwed" (tackon (tackon newdir "FileSystem") @each-name)))
                        (copyfiles
                            (source (tackon "DisKey_3.0/FileSystem" @each-name))
                            (dest (tackon newdir "FileSystem"))
                            (optional nofail force)
                        )
                    )
                )
                (set fstmpbit (+ fstmpbit 1))
            )
        )
    )
)

(if (NOT (= (BITAND -2 language_bits) 0))
    (
        (working
            install_languages
        )
        (set langtmpbit 1)
        (if (NOT (exists (tackon newdir "Catalogs")))
            (makedir (tackon newdir "Catalogs"))
        )
        (foreach
            "DisKey_3.0/Catalogs"
            "#?"
            (
                (if (IN language_bits langtmpbit)
                    (
                        (set thislanguage @each-name)

                        (run ("protect %s rwed" (tackon (tackon (tackon newdir "Catalogs") thislanguage) "DisKey.catalog")))
                        (copyfiles
                            (source (tackon (tackon "DisKey_3.0/Catalogs" thislanguage) "DisKey.catalog"))
                            (dest (tackon (tackon newdir "Catalogs") thislanguage))
                            (optional nofail force)
                        )
                        (run ("protect %s rwed" (tackon (tackon (tackon newdir "Catalogs") thislanguage) "DisKey-AllFS.catalog")))
                        (copyfiles
                            (source (tackon (tackon "DisKey_3.0/Catalogs" thislanguage) "DisKey-AllFS.catalog"))
                            (dest (tackon (tackon newdir "Catalogs") thislanguage))
                            (optional nofail force)
                        )
                        (run ("protect %s rwed" (tackon (tackon (tackon newdir "Catalogs") thislanguage) "DisKey-KickFS.catalog")))
                        (copyfiles
                            (source (tackon (tackon "DisKey_3.0/Catalogs" thislanguage) "DisKey-KickFS.catalog"))
                            (dest (tackon (tackon newdir "Catalogs") thislanguage))
                            (optional nofail force)
                        )
                        (run ("protect %s rwed" (tackon (tackon (tackon newdir "Catalogs") thislanguage) "DisKey-AmigaFS.catalog")))
                        (copyfiles
                            (source (tackon (tackon "DisKey_3.0/Catalogs" thislanguage) "DisKey-AmigaFS.catalog"))
                            (dest (tackon (tackon newdir "Catalogs") thislanguage))
                            (optional nofail force)
                        )

                        (set fstmpbit 0)
                        (foreach
                            "DisKey_3.0/FileSystem"
                            "#?.dkfs"
                            (
                                (if (IN fsmodule_bits fstmpbit)
                                    (    ; *** FOLGENDE ZEILE MUSS NOCH RAUS, WENN ALLE CATALOGS EXISTIEREN!!!
                                        (if (exists ((tackon (tackon "DisKey_3.0/Catalogs" thislanguage) ("DisKey-%s.catalog" (substr @each-name 0 (- (strlen @each-name) 5))))))
                                            (run ("protect %s rwed" (tackon (tackon newdir "Catalogs") thislanguage)))
                                            (copyfiles
                                                (source (tackon (tackon "DisKey_3.0/Catalogs" thislanguage) ("DisKey-%s.catalog" (substr @each-name 0 (- (strlen @each-name) 5)))))
                                                (dest (tackon (tackon newdir "Catalogs") thislanguage))
                                                (optional nofail force)
                                            )
                                        )
                                    )
                                )
                                (set fstmpbit (+ fstmpbit 1))
                            )
                        )

                    )
                )
                (set langtmpbit (+ langtmpbit 1))
            )
        )
    )
)

(copylib
    (prompt copylib_patternlibrary)
    (help @copylib-help)
    (source "DisKey_3.0/Libs/pattern.library")
    (dest "LIBS:")
    (optional nofail)
    (confirm)
)

(copylib
    (prompt copylib_dislibrary)
    (help @copylib-help)
    (source "DisKey_3.0/Libs/dis.library")
    (dest "LIBS:")
    (optional nofail)
    (confirm)
)

(copylib
    (prompt copylib_reqlibrary)
    (help @copylib-help)
    (source "DisKey_3.0/Libs/req.library")
    (dest "LIBS:")
    (optional nofail)
    (confirm)
)